FrogLoader/build.gradle.kts

plugins {
    java
    `java-library`
    id("io.freefair.lombok") version "8.+"
    `maven-publish`
    id("dev.frogmc.meta-update") version "0.0.1-alpha.7"
}

group = "dev.frogmc"
version = "0.0.1-alpha.27"

repositories {
    maven {
        name = "FrogMC Snapshots"
        url = uri("https://maven.frogmc.dev/snapshots")
    }
    maven {
        name = "FrogMC Releases"
        url = uri("https://maven.frogmc.dev/releases")
    }
    mavenCentral()
}

dependencies {
    implementation(libs.thyroxine)
    compileOnly("org.apache.logging.log4j:log4j-slf4j2-impl:2.22.1")
    compileOnly("org.apache.logging.log4j:log4j-api:2.22.1")
    compileOnly("org.apache.logging.log4j:log4j-core:2.22.1")
    compileOnly("com.google.code.gson:gson:2.0")
    compileOnly("com.google.guava:guava:21.0") // Lowest possible version for our code

    api(libs.mixin) {
        exclude(group = "com.google.code.gson")
        exclude(group = "com.google.guava")
    }
    api(libs.mixinextras)
    api(libs.nightconfig)
    api(libs.annotations)
}

java {
    sourceCompatibility = JavaVersion.VERSION_21
    targetCompatibility = JavaVersion.VERSION_21

    withJavadocJar()
    withSourcesJar()
}

tasks.javadoc {
    include("**/api/**")
}

tasks.processResources {
    inputs.property("version", version)

    filesMatching("frog.mod.toml") {
        expand("version" to version)
    }
}

publishing {
    publications {
        create<MavenPublication>("mavenJava") {
            artifactId = "frogloader"
            from(components["java"])
        }
    }

    repositories {
        maven {
            name = "FrogMCSnapshotsMaven"
            url = uri("https://maven.frogmc.dev/snapshots")
            credentials(PasswordCredentials::class)
            authentication {
                create<BasicAuthentication>("basic")
            }
        }

        maven {
            name = "FrogMCReleasesMaven"
            url = uri("https://maven.frogmc.dev/releases")
            credentials(PasswordCredentials::class)
            authentication {
                create<BasicAuthentication>("basic")
            }
        }
    }
}