FrogLoader/build.gradle.kts

plugins {
    java
    `java-library`
    id("io.freefair.lombok") version "8.+"
    `maven-publish`
}

group = "dev.frogmc"
version = "0.0.1-SNAPSHOT"

repositories {
    maven {
        name = "FrogMC Maven/Snapshots"
        url = uri("https://maven.frogmc.dev/snapshots")
    }
    maven {
        name = "FrogMC Maven/Releases"
        url = uri("https://maven.frogmc.dev/releases")
    }
    maven("https://maven.fabricmc.net/")
    maven("https://repo.spongepowered.org/maven")
    mavenCentral()
}

dependencies {
    implementation(libs.thyroxine){
        isTransitive = false
    }
    compileOnly("org.apache.logging.log4j:log4j-slf4j2-impl:3.0.0-beta2")
    compileOnly("org.apache.logging.log4j:log4j-api:3.0.0-beta2")
    compileOnly("org.apache.logging.log4j:log4j-core:3.0.0-beta2")

    api(libs.mixin)
    api(libs.mixinextras)
    implementation(libs.nightconfig)
    api(libs.annotations)
}

java {
    sourceCompatibility = JavaVersion.VERSION_21
    targetCompatibility = JavaVersion.VERSION_21

    withJavadocJar()
    withSourcesJar()
}

tasks.javadoc {
    include("**/api/**")
}

tasks.processResources {
    inputs.property("version", version)

    filesMatching("frog.mod.toml") {
        expand("version" to version)
    }
}

publishing {
    publications {
        create<MavenPublication>("mavenJava") {
            artifactId = "frogloader"
            from(components["java"])
        }
    }

    repositories {
        maven {
            name = "FrogMCSnapshotsMaven"
            url = uri("https://maven.frogmc.dev/snapshots")
            credentials(PasswordCredentials::class)
            authentication {
                create<BasicAuthentication>("basic")
            }
        }

        maven {
            name = "FrogMCReleasesMaven"
            url = uri("https://maven.frogmc.dev/releases")
            credentials(PasswordCredentials::class)
            authentication {
                create<BasicAuthentication>("basic")
            }
        }
    }
}