import java.util.Date

plugins {
    kotlin("jvm") version "2.0.0"
    `java-gradle-plugin`
    `maven-publish`
}

group = "dev.frogmc"
version = "aaa"

repositories {
    maven {
        name = "FrogMC Maven Releases"
        url = uri("https://maven.frogmc.dev/releases")
    }
    maven {
        name = "FrogMC Maven Snapshots"
        url = uri("https://maven.frogmc.dev/snapshots")
    }
    mavenLocal()

    mavenCentral()
}

dependencies {
    implementation("dev.frogmc:thyroxine:0.0.1-alpha.16")
    implementation("org.ow2.asm:asm:9.7")
    implementation("org.ow2.asm:asm-commons:9.7")
    implementation("org.ow2.asm:asm-tree:9.7")
    implementation("com.google.code.gson:gson:2.10.1")
    implementation("org.vineflower:vineflower:1.10.1")
    testImplementation(kotlin("test"))
    implementation("com.electronwill.night-config:toml:3.8.1")
    implementation("com.google.jimfs:jimfs:1.3.0")
}

gradlePlugin {
    plugins {
        create("phytotelma") {
            id = "dev.frogmc.phytotelma"
            implementationClass = "dev.frogmc.phytotelma.PhytotelmaPlugin"
        }
    }
}

tasks.jar {
    manifest {
        attributes(
            "Implementation-Version" to version,
            "Implementation-Date" to Date(),
            "Implementation-Name" to project.name
        )
    }
}

tasks.test {
    useJUnitPlatform()
}
kotlin {
    jvmToolchain(21)
}

publishing {
    publications {

    }

    repositories {
        maven {
            name = "FrogMCSnapshotsMaven"
            url = uri("https://maven.frogmc.dev/snapshots")
            credentials(PasswordCredentials::class)
            authentication {
                create<BasicAuthentication>("basic")
            }
        }

        maven {
            name = "FrogMCReleasesMaven"
            url = uri("https://maven.frogmc.dev/releases")
            credentials(PasswordCredentials::class)
            authentication {
                create<BasicAuthentication>("basic")
            }
        }
    }
}